Ufuidotnet(うふい.net)／Excel「コピペで使える数式：第1日曜日・第1月曜日…第1土曜日の日付を求める数式(1)」

第1日曜日・第1月曜日…第1土曜日の日付を求める数式(1)

Home > PCワンポイントTips（top） > ExcelのワンポイントTips > コピペで使える数式【第1日曜日・第1月曜日…第1土曜日の日付を求める数式(1)】

Excel Version：
2019
2016
2013
2010
2007
2003
2002
2000
97
([4]2020-11-25)

月の最初の日曜日～土曜日の日付を求める数式です。

　この数式は、(1)指定された任意の日付、(2)指定された１日の日付、(3)今日の日付から第1日曜日・第1月曜日…第1土曜日の日付を求める数式です。

index

指定セルの任意の日付から求める数式
 ●第２～第４（第５）月曜日を求める場合
 ●数式を組み立てられるようになりたい人のための解説
指定セルの１日の日付から求める数式
今日の日付から求める数式

　※　Excel2010以降のみで使用する場合は、こちら↓の数式も使えます。
　　　【第1日曜日・第1月曜日…第1土曜日の日付を求める数式(2)】(click here)

１．指定セルの任意の日付から求める数式

　下表中の式、“=DATE(YEAR($B$2),……”をコピペしてお使いください。
　B3セルから順に日曜日～土曜日の各曜日用です。
　$B$2は日付（2017年11月15日）の入ったセル番号、"0654321"～"6543210"は1日の曜日ごとに加える数値(日数)の並びを表しています。
下記の表は、B3～B9セルに例としてB2セルの日付（2017年11月15日(水)）から第１日曜日～第１土曜日の日付計算結果を表示しています。

	A	B	C
1		日付	Ｂ列セルの内容
2	年月日	2017/11/15	2017/11/15
3	第１日曜日	2017/11/5	=DATE(YEAR($B$2),MONTH($B$2),1)+VALUE( MID("0654321",WEEKDAY(DATE(YEAR($B$2),MONTH($B$2),1),1),1)) 又は =DATE(YEAR($B$2),MONTH($B$2),1)+7 -WEEKDAY(DATE(YEAR($B$2),MONTH($B$2),1),2)
4	第１月曜日	2017/11/6	=DATE(YEAR($B$2),MONTH($B$2),1)+VALUE( MID("1065432",WEEKDAY(DATE(YEAR($B$2),MONTH($B$2),1),1),1))
5	第１火曜日	2017/11/7	=DATE(YEAR($B$2),MONTH($B$2),1)+VALUE( MID("2106543",WEEKDAY(DATE(YEAR($B$2),MONTH($B$2),1),1),1))
6	第１水曜日	2017/11/1	=DATE(YEAR($B$2),MONTH($B$2),1)+VALUE( MID("3210654",WEEKDAY(DATE(YEAR($B$2),MONTH($B$2),1),1),1))
7	第１木曜日	2017/11/2	=DATE(YEAR($B$2),MONTH($B$2),1)+VALUE( MID("4321065",WEEKDAY(DATE(YEAR($B$2),MONTH($B$2),1),1),1))
8	第１金曜日	2017/11/3	=DATE(YEAR($B$2),MONTH($B$2),1)+VALUE( MID("5432106",WEEKDAY(DATE(YEAR($B$2),MONTH($B$2),1),1),1))
9	第１土曜日	2017/11/4	=DATE(YEAR($B$2),MONTH($B$2),1)+VALUE( MID("6543210",WEEKDAY(DATE(YEAR($B$2),MONTH($B$2),1),1),1)) 又は =DATE(YEAR($B$2),MONTH($B$2),1)+7 -WEEKDAY(DATE(YEAR($B$2),MONTH($B$2),1),1)

← BACK↑ PAGE TOP

● 第２～第４（第５）月曜日を求める場合

　第２・第３・第４月曜日の日付を求める場合は、第１月曜日の日付に７の倍数を足すと簡単に求められます。
第５月曜日の場合は、該当月における第５月曜日の有無をチェックして、処理を分ける必要があります。

	A	B	C
1		日付	Ｂ列セルの内容
2	年月日	2017/11/15	2017/11/15(水)
3	第１月曜日	2017/11/6	=DATE(YEAR($B$2),MONTH($B$2),1)+VALUE( MID("1065432",WEEKDAY(DATE(YEAR($B$2),MONTH($B$2),1),1),1))
4	第２月曜日	2017/11/13	=DATE(YEAR($B$2),MONTH($B$2),1)+VALUE( MID("1065432",WEEKDAY(DATE(YEAR($B$2),MONTH($B$2),1),1),1))+7
5	第３月曜日	2017/11/20	=DATE(YEAR($B$2),MONTH($B$2),1)+VALUE( MID("1065432",WEEKDAY(DATE(YEAR($B$2),MONTH($B$2),1),1),1))+14
6	第４月曜日	2017/11/27	=DATE(YEAR($B$2),MONTH($B$2),1)+VALUE( MID("1065432",WEEKDAY(DATE(YEAR($B$2),MONTH($B$2),1),1),1))+21
7	第５月曜日	ありません	=IF(MONTH(DATE(YEAR($B$2),MONTH($B$2),1)+VALUE( MID("1065432",WEEKDAY(DATE(YEAR($B$2),MONTH($B$2),1),1),1))+28)= MONTH($B$2),DATE(YEAR($B$2),MONTH($B$2),1)+VALUE( MID("1065432",WEEKDAY(DATE(YEAR($B$2),MONTH($B$2),1),1),1))+28, "ありません")

← BACK↑ PAGE TOP

● 数式を組み立てられるようになりたい人のための解説

　　B2セルの日付から第１月曜日の日付を求める式を例に説明しましょう。

	B	C	解説
1	日付	Ｂ列セルの内容
2	2017/11/15	2017/11/15
3	2017/11/6	="2017/11/1"+5	(1)基本になるのはこの式。まずは月頭の日付から第1月曜日を求めます。 2017年11月1日は水曜日です。月曜日は5日後なので、“2017/11/1”に+5で計算できます。
4	2017/11/1	=DATE(YEAR($B$2),MONTH($B$2),1)	(2)B2セル(2017/11/15)から“2017/11/1”をDATE関数、YEAR関数、MONTH関数を使って作ります。
5	5	=VALUE(MID("1065432",4,1))	(3)1日から最初の月曜日までの日数を表す5ですが、1日が日曜日の場合は+1、月曜だと+0、火曜：+6、水曜：+5、木曜：+4、金曜：+3、土曜：+2となり、1065432の順になります。 "2017/11/1"の場合は、MID関数で文字列の4番目の数字を取り出して使うことにします。VALUE関数で数値化します。
6	5	=VALUE(MID("1065432",WEEKDAY( DATE(YEAR($B$2),MONTH($B$2),1),1),1))	(4)MID関数の取り出す文字位置(4)をWEEKDAY関数を使って自動化します。日付は(2)の式を使って1日の日付にします。
7	2017/11/6	=DATE(YEAR($B$2),MONTH($B$2),1) +VALUE(MID("1065432",WEEKDAY( DATE(YEAR($B$2),MONTH($B$2),1),1),1))	(5)(1)の式の"2017/11/1"を(2)の式で置き換え、同じく(1)の式の5を(4)の式で置き換えて出来上がりです。

← BACK

↑ PAGE TOP

２．指定セルの１日の日付から求める数式

　下表中の式、“=$B$2+VALUE(MID("……”をコピペしてお使いください。
　B3セルから順に日曜日～土曜日の各曜日用です。
　$B$2は日付（2017年11月1日）の入ったセル番号、"0654321"～"6543210"は1日の曜日ごとに加える数値(日数)の並びを表しています。
下記の表は、B3～B9セルに例としてB2セルの日付（2017年11月1日(水)）から第１日曜日～第１土曜日の日付計算結果を表示しています。

	A	B	C
1		日付	Ｂ列セルの内容
2	年月日	2017/11/15	2017/11/15
3	第１日曜日	2017/11/5	=DATE(YEAR($B$2),MONTH($B$2),1)+VALUE( MID("0654321",WEEKDAY(DATE(YEAR($B$2),MONTH($B$2),1),1),1)) 又は =DATE(YEAR($B$2),MONTH($B$2),1)+7 -WEEKDAY(DATE(YEAR($B$2),MONTH($B$2),1),2)
4	第１月曜日	2017/11/6	=DATE(YEAR($B$2),MONTH($B$2),1)+VALUE( MID("1065432",WEEKDAY(DATE(YEAR($B$2),MONTH($B$2),1),1),1))
5	第１火曜日	2017/11/7	=DATE(YEAR($B$2),MONTH($B$2),1)+VALUE( MID("2106543",WEEKDAY(DATE(YEAR($B$2),MONTH($B$2),1),1),1))
6	第１水曜日	2017/11/1	=DATE(YEAR($B$2),MONTH($B$2),1)+VALUE( MID("3210654",WEEKDAY(DATE(YEAR($B$2),MONTH($B$2),1),1),1))
7	第１木曜日	2017/11/2	=DATE(YEAR($B$2),MONTH($B$2),1)+VALUE( MID("4321065",WEEKDAY(DATE(YEAR($B$2),MONTH($B$2),1),1),1))
8	第１金曜日	2017/11/3	=DATE(YEAR($B$2),MONTH($B$2),1)+VALUE( MID("5432106",WEEKDAY(DATE(YEAR($B$2),MONTH($B$2),1),1),1))
9	第１土曜日	2017/11/4	=DATE(YEAR($B$2),MONTH($B$2),1)+VALUE( MID("6543210",WEEKDAY(DATE(YEAR($B$2),MONTH($B$2),1),1),1)) 又は =DATE(YEAR($B$2),MONTH($B$2),1)+7 -WEEKDAY(DATE(YEAR($B$2),MONTH($B$2),1),1)

← BACK↑ PAGE TOP

３．今日の日付から求める数式

　今日の日付から求めるので、今月の第1日曜日・第1月曜日…第1土曜日の日付が求められます。
当然ですが、翌月になると翌月の第1日曜日・第1月曜日…第1土曜日の日付に変わります。
　下表中の式、“=DATE(YEAR(TODAY()),……”をコピペしてお使いください。
　B3セルから順に日曜日～土曜日の各曜日用です。
　"0654321"～"6543210"は1日の曜日ごとに加える数値(日数)の並びを表しています。
下記の表は、B3～B9セルに今日の日付（2017年11月15日(水)）から第１日曜日～第１土曜日の日付計算結果を表示しています。
1.の式の "B$2" を "TODAY()" 関数で置き換えた式です。

	A	B	C
1		日付	Ｂ列セルの内容
2			今日の日付(2017/11/15(水))は TODAY()関数でPCから得られます。 1.式の "B$2" を "TODAY()" 関数で置き換えた式です。
3	第１日曜日	2017/11/5	=DATE(YEAR(TODAY()),MONTH(TODAY()),1)+VALUE( MID("0654321",WEEKDAY(DATE(YEAR(TODAY()),MONTH(TODAY()),1),1),1)) 又は =DATE(YEAR(TODAY()),MONTH(TODAY()),1)+7-WEEKDAY(DATE(YEAR(TODAY()),MONTH(TODAY()),1),2)
4	第１月曜日	2017/11/6	=DATE(YEAR(TODAY()),MONTH(TODAY()),1)+VALUE( MID("1065432",WEEKDAY(DATE(YEAR(TODAY()),MONTH(TODAY()),1),1),1))
5	第１火曜日	2017/11/7	=DATE(YEAR(TODAY()),MONTH(TODAY()),1)+VALUE( MID("2106543",WEEKDAY(DATE(YEAR(TODAY()),MONTH(TODAY()),1),1),1))
6	第１水曜日	2017/11/1	=DATE(YEAR(TODAY()),MONTH(TODAY()),1)+VALUE( MID("3210654",WEEKDAY(DATE(YEAR(TODAY()),MONTH(TODAY()),1),1),1))
7	第１木曜日	2017/11/2	=DATE(YEAR(TODAY()),MONTH(TODAY()),1)+VALUE( MID("4321065",WEEKDAY(DATE(YEAR(TODAY()),MONTH(TODAY()),1),1),1))
8	第１金曜日	2017/11/3	=DATE(YEAR(TODAY()),MONTH(TODAY()),1)+VALUE( MID("5432106",WEEKDAY(DATE(YEAR(TODAY()),MONTH(TODAY()),1),1),1))
9	第１土曜日	2017/11/4	=DATE(YEAR(TODAY()),MONTH(TODAY()),1)+VALUE( MID("6543210",WEEKDAY(DATE(YEAR(TODAY()),MONTH(TODAY()),1),1),1)) 又は =DATE(YEAR(TODAY()),MONTH(TODAY()),1)+7-WEEKDAY(DATE(YEAR(TODAY()),MONTH(TODAY()),1),1)

← BACK↑ PAGE TOP

◆ Excel2010以降のみで使用する場合は、こちら↓の数式も使えます。
　【第1日曜日・第1月曜日…第1土曜日の日付を求める数式(2)】(click here)

← BACK

↑ PAGE TOP

Excel Tips『コピペで使える数式：第1日曜日・第1月曜日…第1土曜日の日付を求める数式(1)』更新記録

2020/11/25: [4] Excel2019を追加。

2017/11/30: [3] HTML5,UTF-8対応。Excel version 2016を追加。[コピー]ボタンを設置。

2012/11/17: [2] 常時現在月例示に対応。

2007/01/30: 新規Tipsとして公開

← BACK

↑ PAGE TOP